HH2 Option 1 source code

[6666]

Here are my results


I am getting the main Tx pulse on pin 6 and the two samples on pin 2 &3

code from post 1
#define TxPulse GPIO1
#define Sample1 GPIO5
#define Sample2 GPIO4
#define PWM GPIO2
#define ADC GPIO0


there are TWO drawings labelled Rev A1 20 June 2009
The first drawing is the old one
drawing 4 matches the code, see pdf

[6666]

To burn the 12f683 I used a simple jdm programmer and Winpic800 software
works very good for 12f683, the programmer (burner) cost a whole $18.00. The software is free, and has a lot of good features.

http://www.ebay.com.au/itm/New-PIC-M...item415cb0ce7e


http://www.winpic800.com//index.php?lang=en

[sinko1]

please post complete shematic.pcb,and hex file.Best regards

[6666]

Its all here in this thread

[6666]

The source code is in post 1
here is my hex file as a text file
save and rename as carlcode.hex or whatever name you want

the pcb mods are in the post above in the pdf

[sinko1]

thanks

[6666]

Altra
could you please tell me how to change your code
so I can change the TX pulse freq from 1000hz to 100hz ?
but still leave it at 100uS pulse width.

thanks
6666

[Altra]

6666,
The TX frequency is controlled by Timer 1 interupt. The frequency is set by changing the values for Timer1H and Timer1L. I just estimated the values below, no time to try it out. If you have problems, I can figure the exact value later this week

Change this:

;Constants
Timer1H equ 0xFC ;Controls Tx Freq - TMR1 interrupt rate TMR1H
Timer1L equ 0x20 ;Controls Tx Freq - TMR1 interrupt rate TMR1L

To: Try these for 100Hz

;Constants
Timer1H equ 0xD8 ;Controls Tx Freq - TMR1 interrupt rate TMR1H
Timer1L equ 0xF4 ;Controls Tx Freq - TMR1 interrupt rate TMR1L

Experiment with different values and watch the frequency change.

[6666]

Thanks Altra will give it a try
cheers
6666

[6666]

Altra would you mind if I ask another question please ?

If i wanted to invert the polarity of the TX and S1 and S2 pulses
that is making them go positive

is it just a matter of changing the H and L at these red points in the code ?
and would doing this mess up pin 7 ??
thanks
6666

;************************************************* *********************
;
; Filename: HH2_PULSE_R2.ASM
; Date: Jan, 2010
; File Version: V0.2
; PIC12F683 @ 8Mhz Intrc_osc
; MPASM Assembler
; Author:Mark Snyder/Altra Electronics
;
; Notes: Circuit, HH2, PCB, Carl Morland, Geotech
; TX pulse triggered on TMR1 interrupt, Tx 100uS @ 1000hz
; Sample_Delay = ADC 0, 1.5uS resolution
; Sample 1 = 15uS
; Sample Spread =200uS
; Sample 2 = 15uS
;************************************************* *********************

list p=12f683
#include <p12f683.inc>

radix dec

errorlevel -302

__config (_INTRC_OSC_NOCLKOUT & _WDT_OFF & _PWRTE_OFF & _MCLRE_OFF & _CP_OFF & _IESO_OFF & _FCMEN_OFF)

;================================================= =============================
; Pin definitions PIC12F683
; Pin 1 Vdd +5vdc Pin 8 Vss GND
; Pin 2 GP5 Sample 2 Pin 7 GP0 AN0 Pot/Sample Delay ISP Data
; Pin 3 GP4 Sample 1 Pin 6 GP1 AN1 TX_pules ISP CLK
; Pin 4 MCLR Pin 5 GP2 PWM Out
;================================================= =============================

; #Defines
#define TX_PULSE GPIO,1 ;PIN 6
#define SAMPLE_1 GPIO,4 ;PIN 3
#define SAMPLE_2 GPIO,5 ;PIN 2
;Constants
Timer1H equ 0xFC ;Controls Tx Freq - TMR1 interrupt rate TMR1H
Timer1L equ 0x20 ;Controls Tx Freq - TMR1 interrupt rate TMR1L

PR2_con equ b'11001111' ;PWM
CCPR1L_con equ b'01100111' ;PWM
CCP1CON_con equ b'00111100' ;PWM
T2CON_con equ b'00000111' ;PWM

;Variables
CBLOCK 0x20 ;Reserve Ram for Variables start 20h

w_temp: 1 ; variable used for context saving
status_temp: 1 ; variable used for context saving

SAMPLE_DELAY: 1 ;Sample Delay Variable
AD_LO: 1 ;ADRESL Var
AD_HI: 1 ;ADRESH Var
temp1: 2 ;Temp Variable
endc

;************************************************* *********************

org 0x00 ; Reset vector
call SetupPWM ; To disable PWM ";" this line out
goto main ; Go to beginning of program

org 0x04 ; Interrupt vector
movwf w_temp ; Save off current W register contents
movf STATUS,w ; Move status register into W register
movwf status_temp ; Save off contents of STATUS register

; check for TMR1 rollover
banksel PIR1
btfss PIR1, TMR1IF ; TMR1 rollover?
goto Jump_ISR

banksel TMR1L
movlw Timer1L ; Reload TMR1
movwf TMR1L
banksel TMR1H
movlw Timer1H
movwf TMR1H
;Interupt Service Routine******************************************* *******
;TX_PULSE
bcf TX_PULSE ;GPIO.1 Low
movlw .67 ;67 x 1.5uS = 100.5uS Tx pulse width
movwf temp1
decfsz temp1,1
goto $-1
bsf TX_PULSE ;GPIO.1 High
;Sample Delay

movfw SAMPLE_DELAY ;((0 to 255) x 1.5uS )+ 1 = 3 to 383uS
addlw 0x01 ;Sets minimum sample delay-never zero
movwf temp1
decfsz temp1,1
goto $-1
;Sample 1
bcf SAMPLE_1 ;GPIO.4 Low
movlw .10 ;10 x 1.5uS = 15uS Sample
movwf temp1
decfsz temp1,1
goto $-1
bsf SAMPLE_1 ;GPIO.4 High
;Sample Spread Delay
movlw .133 ;132 x 1.5uS = 199.5uS Spread between samples
movwf temp1
decfsz temp1,1
goto $-1
;Sample 2
bcf SAMPLE_2 ;GPIO.5 Low
movlw .10 ;10 x 1.5uS = 15uS Sample
movwf temp1
decfsz temp1,1
goto $-1
bsf SAMPLE_2 ;GPIO.5 High
;END ISR*********************************************** ********************
;Restore registors -Reset Interrupt flag
banksel PIR1
bcf PIR1, TMR1IF ; clear interrupt flag

Jump_ISR
movf status_temp,w ; retrieve copy of STATUS register
movwf STATUS ; restore pre-isr STATUS register contents
swapf w_temp,f
swapf w_temp,w ; restore pre-isr W register contents
retfie ; return from interrupt

;================================================= ==============================
;Initialize
main

banksel OSCCON
movlw b'01110101' ;SET INTERNAL OSC TO 8MHZ
movwf OSCCON

; Set up direction of GP I/O pins
banksel TRISIO
movlw b'00000001' ;GPIO.0 AD INPUT, GPIO 1 TO 5 OUTPUTS
movwf TRISIO

; Set up comparator
banksel CMCON0
movlw b'00000111' ;COMPARATOR OFF
movwf CMCON0

; Set up A/D converter
banksel ANSEL
movlw b'01010001' ;FOSC/16-GPIO.0=AN0
movwf ANSEL

banksel ADCON0
movlw b'00000001' ;AD result left justify, 8bit resolution
movwf ADCON0

; Initialize interrupts
banksel INTCON
movlw b'01000000' ;Enable peripheral interrupts
movwf INTCON

banksel PIE1
movlw b'00000001' ;Enable TMR1 overflow interrupt
movwf PIE1

banksel PIR1
movlw b'00000000'
movwf PIR1

; Initialize TMR1
banksel T1CON
movlw b'00010101'
movwf T1CON

; 8 MHZ internal oscillator
; Fosc/4 = 2 MHZ = 500nS per clock
; with 1:2 prescaler
banksel TMR1L
movlw Timer1L ;0x20
movwf TMR1L
banksel TMR1H
movlw Timer1H ;0xFC
movwf TMR1H

banksel INTCON
bsf INTCON, GIE ; enable interrupts
;================================================= ======================
; Loop until next TMR1 interrupt
Idle_loop

bsf ADCON0,0 ;ADC on
nop ;Delay
nop
nop
nop
nop
nop
nop
nop
nop
nop
bsf ADCON0,1 ;Start A/D conversion
btfsc ADCON0,1 ;AD complete skip
goto $-1 ;loop
banksel ADRESH
movfw ADRESH
movwf SAMPLE_DELAY ;Store AD hibyte
banksel ADRESL
movfw ADRESL
movwf AD_LO ;not used
bcf STATUS,RP0
goto Idle_loop

SetupPWM
; Initialize PWM
banksel PR2
movlw PR2_con ;b'11001111' ;600hz 50%
movwf PR2
banksel T2CON
movlw T2CON_con; b'00000111' ;600hz 50%
movwf T2CON
clrf CCPR1L
movlw CCP1CON_con; b'00111100' ;600hz 50%
movwf CCP1CON
movlw CCPR1L_con; b'01100111' ;600hz 50%
movwf CCPR1L ;
return

END

[Altra]

6666,

TIMER1L and TIMER1H only affect the TX frequency. See post #38. The reason there is an L and H is because it is a 16 bit register. But the pic chip is only an 8bit device. Therefore to read and write to this register it takes two operations. A (H)igh byte and a (L)ow byte.

To change the the polarity of the TX and samples. There are two commands bcf and bsf. bcf sets the pin to low or 0. bsf sets the pin high or 1.
bcf = bit clear in f ............ bsf = bit set in f

If you want to change which pins are assigned to sample or tx change these

(original)
; #Defines
#define TX_PULSE GPIO,1 ;PIN 6
#define SAMPLE_1 GPIO,4 ;PIN 3
#define SAMPLE_2 GPIO,5 ;PIN 2

(with samples reversed)
; #Defines
#define TX_PULSE GPIO,1 ;PIN 6
#define SAMPLE_1 GPIO,5 ;PIN 2
#define SAMPLE_2 GPIO,4 ;PIN 3

Try this, I reversed the polarity of the Tx and samples. All I did was changed the bcf's to bsf's and bsf's to bcf's.

;Interupt Service Routine******************************************* *******
;TX_PULSE
bsf TX_PULSE ;GPIO.1 high
movlw .67 ;67 x 1.5uS = 100.5uS Tx pulse width
movwf temp1
decfsz temp1,1
goto $-1
bcf TX_PULSE ;GPIO.1 low
;Sample Delay
movfw SAMPLE_DELAY ;((0 to 255) x 1.5uS )+ 1 = 3 to 383uS
addlw 0x01 ;Sets minimum sample delay-never zero
movwf temp1
decfsz temp1,1
goto $-1
;Sample 1
bsf SAMPLE_1 ;GPIO.4 high
movlw .10 ;10 x 1.5uS = 15uS Sample
movwf temp1
decfsz temp1,1
goto $-1
bcf SAMPLE_1 ;GPIO.4 low
;Sample Spread Delay
movlw .133 ;132 x 1.5uS = 199.5uS Spread between samples
movwf temp1
decfsz temp1,1
goto $-1
;Sample 2
bsf SAMPLE_2 ;GPIO.5 high
movlw .10 ;10 x 1.5uS = 15uS Sample
movwf temp1
decfsz temp1,1
goto $-1
bcf SAMPLE_2 ;GPIO.5 Low
;END ISR*********************************************** ********************

[6666]

Hi Altra
thanks for the reply, much appreciated
I can see what I need to do now
and will give it a try
cheers
6666

[6666]

Hi Altra
thanks it works

had a bit of a hard time compiling the code this time
finally got it compiled in mplab asm, it gave me lots of warnings

but it works, pin 7 works ok for the sample delay to
cheers
6666

here is the hex if anybody wants it
its altra's code moded to give positive going pulses

:020000040000FA
:040000006B20322817
:08000800A0000308A10083120F
:100010000C1C2D28831220308E008312FC308F00A0
:1000200085144330A500A50B132885102208013E36
:10003000A500A50B192805160A30A500A50B1E283A
:1000400005128530A500A50B232885160A30A500CA
:10005000A50B2828851283120C1021088300A00EFE
:10006000200E0900831675308F008316013085003D
:10007000831207309900831651309F00831201309C
:100080009F00831240308B00831601308C00831256
:1000900000308C00831215309000831220308E00C7
:1000A0008312FC308F0083128B171F140000000096
:1000B0000000000000000000000000000000000040
:1000C0009F149F18612883121E08A20083161E0821
:1000D000A300831255288316CF3092008312073075
:0E00E000920093013C309500673093000800B9
:02400E00D433A9
:00000001FF

[johnandles]

Cheers for posting hex,and thanks to Altra for his quick reply and re-asm.
A question for 6666.
What was the reason to change frequency...are you hunting the holy yellow grail?
Regards,
and Merry Xmas to all
John

[6666]

Hi John
your welcome for the hex, I use a jdm burner for 12f683
re the Freq I am just experimenting with some ideas
and the 1000 pps was a bit high, BTW the above hex is still 1000 pps

Notes: Circuit, HH2, PCB, Carl Morland, Geotech
; TX pulse triggered on TMR1 interrupt, Tx 100uS @ 1000hz
; Sample_Delay = ADC 0, 1.5uS resolution
; Sample 1 = 15uS
; Sample Spread =200uS
; Sample 2 = 15uS

cheers 6666