AD797 pre amp on my IDX - not easy

[golfnut]

Im trying one - just for fun. I am not having any success in making it work. Tried some old chips and thought they were broken, splashed on a new one it too isnt working for me.


I dont get any output from the op amp unless I have v large input signal (volts) from a huge lump of iron - then I get rail to rail output squared off. Another odd thing is, as I reducenthe signal in, the output DC level flips to the positive rail an stays there?


where Im at..

Im using a double sided board with copper flood on reverse and a bit on top with vias thru - attempt for solid ground work
Decoupling 100p and 100nF right on the pos and neg rails.
Ive got a 20k pot to null the offset - but o/p still sits at -3.5v and pot doesnt move this?
I put a couple of diodes in the gnd lead of the 8v reg to jack it - I have +5 and -5v rails.

If I disconnect my coil - my machine beeps all the time, I can see a oscillation on 797 output, it has approx square wave with some RF - which I like because it shows the amp is working and I expect this performance with unterminated pin 3 (input)



Any clue what to try next - I need to get cracking on a farm, so if I cant use this amp Ill rip it off and go back to original.

S

[golfnut]

I couldnt sort this, and went back to original preamp.

Had a go on new farm - tight hard clay madness - few finds.

I did get what appears to be an old rifled bullet Ill post pic if any old bullet experts out there..

S

[Carl-NC]

Don't know, I've used a 797 before with no problems.

[ODM]

Can you post your schematic, and perhaps a photo of your physical layout?

The op amp has input protection, but if it has railed the input protection diodes and input stage itself might have been affected if there have been no input current limiting means. Damaged op amps can (and usually will) behave in curious ways. With high GBW/slew-rate parts it's necessary to keep the layout very clean and have stable power supplies.

[golfnut]

Hi, the schematic is the IDX preamp. But with a 797.

Im trying to model it ltspice - Ive put a directive in and have the model pasted in the schematic . Prob here is the opamp2 (generic) that the user can edit has no compensation pin allocation. So the AD797 model does not line up and it throws an error.

"The instance has fewer connection terminals than the definition"

Either I need to add a pin to the model or just get a .subckt of a 797


Anyone help with either of the above pls. S

[golfnut]

I try to make new auto generated part by right click of subckt name in model as per video.

I get an error - my sucbircuit I made from pasting model content from AD into a copy of an existing subcirkt file in library and renaming it

Prob is, when I save new copy with my new name, the new model shows as a txt file. when I try to alter the .txt to a sub it reads AD797.sub rather than filename AD797 with attribute SUB.

S

[golfnut]

Could someone try to make a new component "Autogenerate part by right click on subcircuit name in blue. I get error cant autogenerate part.... All of the how to's and teach vids say do this...??

* AD797 SPICE Macro-model
* Description: Amplifier
* Generic Desc: 10/30V, BIP, OP, Low THD, Low Noise, 1X
* Developed by: AAG / PMI
* Revision History: 08/10/2012 - Updated to new header style
* 1.0 (10/1992)
* Copyright 1992, 2012 by Analog Devices, Inc.
*
* Refer to http://www.analog.com/Analog_Root/st...e_general.html for License Statement. Use of this model
* indicates your acceptance with the terms and provisions in the License Statement.
*
* BEGIN Notes:
*
* Not Modeled:
*
* Parameters modeled include:
*
* END Notes
*
* Node assignments
* non-inverting input
* | inverting input
* | | positive supply
* | | | negative supply
* | | | | output
* | | | | | decompensation
* | | | | | |
.SUBCKT AD797 1 2 99 50 38 14
*
* INPUT STAGE & POLE AT 500 MHz
*
IOS 1 2 DC 50E-9
CIND 1 2 20E-12
CINC1 1 98 5E-12
GRCM1 1 98 POLY(2) 1 31 2 31 (0,5E-9,5E-9)
GN1 0 1 44 0 1E-3
CINC2 2 98 5E-12
GRCM2 2 98 POLY(2) 1 31 2 31 (0,5E-9,5E-9)
GN2 0 2 47 0 1E-3
EOS 9 3 POLY(1) 22 31 25E-6 1
EN 3 1 41 0 0.1
D1 2 9 DX
D2 9 2 DX
Q1 5 2 4 QX
Q2 6 9 4 QX
R3 97 5 0.5172
R4 97 6 0.5172
C2 5 6 3.0772E-10
I1 4 51 100E-3
EPOS 97 0 99 0 1
ENEG 51 0 50 0 1
*
* INPUT VOLTAGE NOISE GENERATOR
*
VN1 40 0 DC 2
DN1 40 41 DEN
DN2 41 42 DEN
VN2 0 42 DC 2
*
* +INPUT CURRENT NOISE GENERATOR
*
VN3 43 0 DC 2
DN3 43 44 DIN
DN4 44 45 DIN
VN4 0 45 DC 2
*
* -INPUT CURRENT NOISE GENERATOR
*
VN5 46 0 DC 2
DN5 46 47 DIN
DN6 47 48 DIN
VN6 0 48 DC 2
*
* GAIN STAGE & DOMINANT POLE AT 7.33 Hz
*
EREF 98 0 31 0 1
G1 98 10 5 6 10
R7 10 98 10
E1 99 11 POLY(1) 99 31 -2.294 1
D3 10 11 DX
E2 12 50 POLY(1) 31 50 -2.294 1
D4 12 10 DX
G2 98 13 10 31 1E-3
R8 13 98 10
G3 99 14 98 13 34.558E-3
G4 99 16 98 98 34.558E-3
G5 14 15 15 14 20E-3
G6 16 17 17 14 20E-3
R9 15 18 400
R10 17 18 400
E3 18 98 16 98 1
R11 16 98 4.3406E8
C5 16 98 50E-12
V1 99 19 DC 2.2542
D5 16 19 DX
V2 20 50 DC 2.2542
D6 20 16 DX
RDC 14 98 1E15
*
* COMMON-MODE GAIN NETWORK WITH ZERO AT 1.35 kHz
*
ECM 21 98 POLY(2) 1 31 2 31 (0,158.11E-3,158.11E-3)
RCM1 21 22 1
CCM 21 22 1.1789E-4
RCM2 22 98 1E-6
*
* POLE-ZERO PAIR AT 3.9 MHz/10 MHz
*
GPZ 98 23 16 98 1
RPZ1 23 98 1
RPZ2 23 24 0.63934
CPZ 24 98 24.893E-9
*
* NEGATIVE ZERO AT -300 MHz
*
ENZ 25 98 23 31 1E6
RNZ1 25 26 1
CNZ 25 26 -5.3052E-10
RNZ2 26 98 1E-6
*
* POLE AT 300 MHz
*
GP2 98 27 26 31 1
RP2 27 98 1
CP2 27 98 5.3052E-10
*
* POLE AT 500 MHz
*
GP3 98 28 27 31 1
RP3 28 98 1
CP3 28 98 3.1831E-10
*
* POLE AT 500 MHz
*
GP4 98 29 28 31 1
RP4 29 98 1
CP4 29 98 3.1831E-10
*
* OUTPUT STAGE
*
VW 29 30 DC 0
RDC1 99 31 23.25E3
CDC 31 0 1E-6
RDC2 31 50 23.25E3
GO1 98 32 37 30 25E-3
DO1 32 33 DX
VO1 33 98 DC 0
DO2 34 32 DX
VO2 98 34 DC 0
FDC 99 50 POLY(2) VO1 VO2 7.56E-3 1 1
VSC1 35 37 0.945
DSC1 30 35 DX
VSC2 37 36 0.745
DSC2 36 30 DX
FSC1 37 0 VSC1 1
FSC2 0 37 VSC2 1
GO3 37 99 99 30 25E-3
GO4 50 37 30 50 25E-3
RO1 99 37 40
RO2 37 50 40
LO 37 38 10E-9
*
* MODELS USED
*
.MODEL QX NPN(BF=2E5)
.MODEL DX D(IS=1E-15)
.MODEL DEN D(IS=1E-12 RS=6.3708E3 AF=1 KF=1.59E-15)
.MODEL DIN D(IS=1E-12 RS=474 AF=1 KF=7.816E-15)
.ENDS AD797

[golfnut]

Is there a chance I bought the wrong amp as there is 2 types of 797.

http://uk.rs-online.com/web/c/?sra=o...7&x=-490&y=-21

I got the cheaper one -ARZ which appears to have the hotter BW and may explain my fail?

[golfnut]

cant take picture of layout, drwg instead


s

[golfnut]

Got this reply from AD ..

"Steve,

This is central applications for the Americas. I have copied central apps for Europe above.
They should be able to assist you.

However, I would point out that the thermal noise of a 170k resistor is 52 nV/rt-Hz, so the 0.9 nV/rt-Hz of the AD797 is wasted.
Also, input bias current of the AD797 is about 1 uA, so you have about 170 mV of induced offset. The input voltage range and
output swing only gets within 3-4V of either rail, so the AD797 is not really meant to run on +/-5V, but rather +/-15V. Finally,
The AD797 has a huge amount of gain at high frequencies, so you need a four layer board and two bypass caps on each
supply as described in the apps section. Maybe an ADA4841-1, ADA4004-1, OP37 or AD8671 would be better.
Also see AN-940.

Harry
"
S

[Davor]

You might wish to slash the resistances of 1k and 170k to 1/10 of their current value (this should take care of noise and offset), and place something like a 3k3 or 10k resistor between pins 2 and 3 (often helps at switch-on, and in absence of source impedance). Also you may consider something like 100ohm between pin6 and everything else (which helps coping with uncooperative loads)