Rx and Tx coils in PI

[Teleno]

Can someone point me to a thread where this matter is discussed?

I'm simulating a PI with two coils and damping seems impossible. Even at low R's.

Tx coil: 40uH, 0.8ohm, 40pF, 1.9A, theroretical damping resistor: 500ohm
Rx coil: 160uH, 1.6ohm, 80pF, theroretical damping resistor: 700ohm
Target: 0.333uH, 0.333ohm (1us tau).
Coupling coefficients:

Tx/Rx: 0.9
target/TX & target/Rx: 0.01

Current in Tx coil looks awful:

.

any pointers on this?

[Tinkerer]

Can someone point me to a thread where this matter is discussed?

I'm simulating a PI with two coils and damping seems impossible. Even at low R's.

Tx coil: 40uH, 0.8ohm, 40pF, 1.9A, theroretical damping resistor: 500ohm
Rx coil: 160uH, 1.6ohm, 80pF, theroretical damping resistor: 700ohm
Target: 0.333uH, 0.333ohm (1us tau).
Coupling coefficients:

Tx/Rx: 0.9
target/TX & target/Rx: 0.01

Current in Tx coil looks awful:

.

any pointers on this?

Just looking at the same problem with a real coil TX and separate RX assembly.

TX coil self resonant frequency = 1.04MHz
RX coil self resonant frequency = 1.400MHz

So the next thing I will do is to see if making the 2 coils of the same Tau makes a difference.

[Teleno]

Just looking at the same problem with a real coil TX and separate RX assembly.

TX coil self resonant frequency = 1.04MHz
RX coil self resonant frequency = 1.400MHz

So the next thing I will do is to see if making the 2 coils of the same Tau makes a difference.

I guess I've figured out why virtually all PI designs are monocoil.

Perhaps a differential RX coil arrangement wiil do. Anyway my ngspice chokes on it.

[Davor]

Perhaps you could show your schematic so that we can see what's going on? You mentioned Rx to Tx coupling of 0.9? That's a lot. Most arrangements are induction balanced and coupling is well under 0.1

[Carl-NC]

I'm not sure I've ever simulated a 2-coil PI, but they're easy to build. I'll go with Davor, your coupling is too high, although I've also built a highly coupled TX/RX coil and it worked fine.

[Teleno]

This is my simulation circuit:



There are significant differences between ngspice and LTspice simulations even though the components are the same. I have no idea why.

For example, see the different currents in the Tx coils (green: ngspice, yellow: LTspice), ngspice is seen more capacitance ????



Timing is the same, just skewed the signals to better see the the differences.

BS170 is not in the LTspice library. You can use it by copying these files:

BS170.ZIP


to the "lib\sym" folder (.asy) and the "lib\sub" folder (.sub) and including a SPICE directive in your schematic: ".lib C:\Documents_from_Desktop\LTspiceIV\lib\sub\BS170. sub" .

This is the netlist for ngspice:

*
*  ZETEX  BS170 Mosfet Spice Subcircuit   Last revision  3/5/00
*
.SUBCKT BS170 1 2 3
**************************************
*      Model Generated by MODPEX     *
*Copyright(c) Symmetry Design Systems*
*         All Rights Reserved        *
*    UNPUBLISHED LICENSED SOFTWARE   *
*   Contains Proprietary Information *
*      Which is The Property of      *
*     SYMMETRY OR ITS LICENSORS      *
*Commercial Use or Resale Restricted *
*   by Symmetry License Agreement    *
**************************************
* Model generated on Mar 29, 04
* MODEL FORMAT: SPICE3
* Symmetry POWER MOS Model (Version 1.0)
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source
M1 9 7 8 8 MM L=100u W=100u
* Default values used in MM:
* The voltage-dependent capacitances are
* not included. Other default values are:
*   RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM NMOS LEVEL=1 IS=1e-32
+VTO=3.30828 LAMBDA=8.59847 KP=12.3217
+CGSO=6.31523e-07 CGDO=2.58372e-08
RS 8 3 2.67458
D1 3 1 MD
.MODEL MD D IS=1e-06 RS=1.38238 N=0.6 BV=600
+IBV=0.0001 EG=1 XTI=4 TT=0
+CJO=9.94504e-11 VJ=0.5 M=0.564013 FC=0.1
RDS 3 1 1.3e+10
RD 9 1 5.83469
RG 2 7 61.0848
D2 4 5 MD1
* Default values used in MD1:
*   RS=0 EG=1.11 XTI=3.0 TT=0
*   BV=infinite IBV=1mA
.MODEL MD1 D IS=1e-32 N=50
+CJO=6.71415e-11 VJ=0.5 M=0.9 FC=1e-08
D3 0 5 MD2
* Default values used in MD2:
*   EG=1.11 XTI=3.0 TT=0 CJO=0
*   BV=infinite IBV=1mA
.MODEL MD2 D IS=1e-10 N=0.4 RS=3e-06
RL 5 10 1
FI2 7 9 VFI2 -1
VFI2 4 0 0
EV16 10 0 9 7 1
CAP 11 10 6.71416e-11
FI1 7 9 VFI1 -1
VFI1 11 6 0
RCAP 6 10 1
D4 0 6 MD3
* Default values used in MD3:
*   EG=1.11 XTI=3.0 TT=0 CJO=0
*   RS=0 BV=infinite IBV=1mA
.MODEL MD3 D IS=1e-10 N=0.4
.ENDS BS170

L1 N003 N003b 40uH
R_LEAK N003b N006 0.8R
C_PARASITIC N003 N006 40e-12

L2 N004 N004b 160uH
R_LEAK2 N004b 0 1.6R
C_PARASITIC2 N004 0 805e-12

L3 0 N001 0.333u
R3 0 N001 0.333

R1 N003 N006 500
R2 N004 0 700
X_M1 N007 N008 0 BS170
D1 N006 N007 MUR460
V2 N002 0 18V
V1 N008 0 PULSE(0 9 2u 60n 60n 40u 1s)
D2 N005 0 GSD2004WV
D3 0 N005 GSD2004WV
R4 N005 N004 3300
R5 N003 N002 9
.model GSD2004WV D Is=.01p Rs=1.6 N=1 Cjo=5p tt=50n
.model MUR460 D Is=149n Rs=.0384 N=2 EG=1.285 XTI=.5 BV=800 IBV=1e-05 Cjo=126.4p Vj=1.34 M=.52 tt=44.4n
K1 L1 L3 0.01
K2 L2 L3 0.01
K3 L1 L2 0.9

.end

The netlist for LTspice is:

* C:\Documents_from_Desktop\LTspiceIV\PI.asc
L1 P001 N011 40µ
L2 P002 0 160µ Rser=1.6 Cpar=80p
L3 0 N001 0.333µ
R3 N001 0 0.333
R1 N005 N011 500
R2 N008 0 700
D1 N011 N013 MUR460
V2 N004 0 18V
V1 N015 0 PULSE(0 9 2u 60n 60n 40u 1s)
D2 N009 0 GSD2004W-V
D3 0 N009 GSD2004W-V
R4 N009 N008 3.3K
R5 N005 N004 9
XU1 N013 N015 0 BS170
R7 N008 P002 1.6
R8 P001 N005 0.8
C1 N008 0 80p
C2 N005 N011 40p
.model D D
.lib C:\Documents_from_Desktop\LTspiceIV\lib\cmp\standard.dio
.tran 0 70u 0 1n
K1 L1 L3 0.01
K2 L2 L3 0.01
K3 L1 L2 0.9
.lib C:\Documents_from_Desktop\LTspiceIV\lib\sub\BS170.sub
.backanno
.end

[Qiaozhi]

You must a small difference in the circuit that was entered in LTSpice, as I've just run your NGSpice netlist directly in LTSpice (after adding the missing .tran statement) and the results look exactly the same.

[Teleno]

You must a small difference in the circuit that was entered in LTSpice, as I've just run your NGSpice netlist directly in LTSpice (after adding the missing .tran statement) and the results look exactly the same.

Thanks! ngspice doesn't understand some parameters in the MUR460 and GSD2004WV LTspice models, that must be it.