Announcement

**ivconic** · 08-15-2019, 05:44 AM

I am "ivconic" and not "iconic". Ivconic as shorter from Ivica Conic.
Maybe i will become "iconic" one day, when i die. But i am sure i will not give a damn on that than.
Cold and white, pretty pale, covered with soil; nothing "iconic" in that! Except maybe in worms eyes...

...
Yes it is my circuit. I think i posted it somewhere on forum. Along with Atmega code for it.
Now, code is not genuine mine. I took Joop's code and adapted it for that purpose.
It really works alright.
I had "big" ambitious plans with that than, but than i gave up. Since i had more important things to do.

Code:

#include <Wire.h> 
#include <LiquidCrystal_I2C.h>
#include <LCDBitmap.h>
LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);
LCDBitmap bitmap(&lcd, 12, 0);
#define DIGITAL_OUT PORTB
#define TX_PIN_A 5       // 13     
#define SAMPLE_PIN_B 4   // 12 
#define SAMPLE_PIN_C 3   // 11
unsigned int Sample1Delay = 65295;
static int value;
static int Mikrosekunde;


void setup ()
{
Generator (); 
InitTimer2 ();
InitTimer1 ();
TCNT2 = 200;  // Set the timer
//*********************
Serial.begin(1200);
 lcd.begin(16,2);
 welcome();
}


//***************************************************************************************************
void VoidDelay (unsigned int n)
{
n += 12; // Adjust for fixed error (approx 0.75us) // n += 235; // Adjust for fixed error (approx 15us) // n += 12;
TCNT1 = n; // Load the counter
bitSet (TIFR1, TOV1); // Clear the flag
while (!(TIFR1 & (1<<TOV1))) {;} // Wait for a flag
}
//***************************************************************************************************
void loop ()
{
serial_radno1(); 
lcd_delay_ispis();      
      


}
//***************************************************************************************************
void InitTimer1 (void)
{
TCCR1A = 0;
TCCR1B = 0;
bitClear (TIMSK1, TOIE1); 
TCNT1 = 0; 
TCCR1B = 0x01; 
}




//***************************************************************************************************
void InitTimer2 (void)
{
TCCR2A = 0;
TCCR2B = 0;
bitSet (TIMSK2, TOIE2); // Enable Timer2 interrupt, TIMSKx, Timer/Counter Interrupt Mask Register
TCCR2B = 0x05; // Prescaler = /128 (8 us resolution)
}


//**************************************************************************************************
void Generator (void)
{
DDRB = B00111111; 
}
void ReadDelayPot (void)
{
value = analogRead(A3); // Wait for the ADC to finish
Sample1Delay = 65535 - 16 - value; 
Mikrosekunde = (65535 -Sample1Delay)/16;
}


// ISR() is the interrupt service routine for Timer2. The main loop is 
// triggered off this interrupt and must be completed before the next 
// interrupt.
ISR (TIMER2_OVF_vect)
{
TCNT2 = 47; // Reset the timer // 255-208 -> 1664us (~600 Hz)
//******************************** MAIN PULSE - TX ******************************
DIGITAL_OUT |= (1<<TX_PIN_A);  // digitalWrite (TX_PIN_A, HIGH);                  
VoidDelay (63935);  // 65535-63935=1600, 1600/16=100uS
DIGITAL_OUT &= ~(1<<TX_PIN_A);  // digitalWrite (TX_PIN_A, LOW);                  
//******************************** MAIN DELAY ***********************************
VoidDelay (Sample1Delay); // Main Delay pauza
//****************************** MAIN DELAY PULSE *******************************
DIGITAL_OUT |= (1<<SAMPLE_PIN_B);  // digitalWrite (SAMPLE_PIN_B, HIGH);             
VoidDelay (64850); // 65535-64850=685, 685/16=42,8125 uS
DIGITAL_OUT &= ~(1<<SAMPLE_PIN_B); // digitalWrite (SAMPLE_PIN_B, LOW);            
//******************************** EF DELAY *************************************
VoidDelay (65135); // 65535-65135=400, 400/16=25uS
//****************************** EF DELAY PULSE *********************************
DIGITAL_OUT |= (1<<SAMPLE_PIN_C);  // digitalWrite (SAMPLE_PIN_C, HIGH);                 
VoidDelay( 64850); // 65535-64850=685, 685/16=42,8125 uS
DIGITAL_OUT &= ~(1<<SAMPLE_PIN_C); // digitalWrite (SAMPLE_PIN_C, LOW);
//******************************** EF+TX DELAY **********************************
VoidDelay( 64850); // 65535-64850=685, 685/16=42,8125 uS
             
ReadDelayPot();
// The remaining routines are where extra processing gets done. It is critical 
// that all processing is complete before the next TCNT2 interrupt occurs, which 
// depends on the TX pulse rate, TX pulse width, and sampling time. If the pulse 
// rate = 600Hz, pulse width = 100us, and max sampling time = 35us then the 
// processing time available is 1667us - 100us - 35us = 1532us. With a 16MHz
// clock we have an instruction cycle of 0.0625us, so there is time for 24512 code
// instructions, including calls and returns.
}




void welcome()
{
 lcd.clear ();
 lcd.setCursor(2, 0);
 lcd.print("BARRACUDA");
 bitmap.begin();  
 bitmap.home();
 for (byte x=0; x<=4; x++) 
  {
    bitmap.line(x, BITMAP_H-1, x+BITMAP_H-1, 0, ON, NO_UPDATE);  
    bitmap.line(x, 0, x+BITMAP_H-1, BITMAP_H-1, ON, NO_UPDATE);  
  }
  bitmap.update();   
}
void lcd_delay_ispis()
{
      lcd.setCursor(0, 1);
      lcd.print("D=");
      lcd.print(Mikrosekunde);
      lcd.print("uS ");
      delay(50);
} 
void serial_radno1()
{
  Serial.print("Analogue Value= ");  
  Serial.print(value);
  Serial.println();
  Serial.print("Sample1Delay= "); 
  Serial.print(Sample1Delay);
  Serial.println(); 
  Serial.print("Mikrosekunde= ");
  Serial.print(Mikrosekunde);
  Serial.print("uS");
  Serial.println();
}

**ivconic** · 08-15-2019, 06:10 AM

I had previously finished Barracuda, lying in a box for quite a while.
What i did? I simply took out the 40106 chip and put wires in the ic socket, connecting spots with Arduino UNO.
I even had a video, but i think i deleted it, i don't have it no more.
LCD is with I2C adapter. Irrelevant. You can comment all the lines for LCD and serial monitor, to make things simpler.
Main timings schedule was suggested by Davor. Although is very easy to change it.
Pot at analog input affects only the main delay.
Code can be extended with another pot for second delay. But that's not making any sense on one channel PI detector.
If i recall correctly; at the time i planned to add another channel and introduce second pot. Which is doable.
As for the LCD, overall there are enough more cycles free to use them for writing and drawing something on LCD.
Anybody more enthusiastic than me now; can do the very interesting small "digital" PI project from this.

**ivconic** · 08-15-2019, 06:30 AM

Same code cleared from LCD and serial monitor part.

Code:

#define DIGITAL_OUT PORTB
#define TX_PIN_A 5       // 13     
#define SAMPLE_PIN_B 4   // 12 
#define SAMPLE_PIN_C 3   // 11
unsigned int Sample1Delay = 65295;
static int value;
static int Mikrosekunde;
void setup ()
{
Generator (); 
InitTimer2 ();
InitTimer1 ();
TCNT2 = 200;  // Set the timer
}
void VoidDelay (unsigned int n)
{
n += 12; // Adjust for fixed error (approx 0.75us) // n += 235; // Adjust for fixed error (approx 15us) // n += 12;
TCNT1 = n; // Load the counter
bitSet (TIFR1, TOV1); // Clear the flag
while (!(TIFR1 & (1<<TOV1))) {;} // Wait for a flag
}
void loop ()
{
}
void InitTimer1 (void)
{
TCCR1A = 0;
TCCR1B = 0;
bitClear (TIMSK1, TOIE1); 
TCNT1 = 0; 
TCCR1B = 0x01; 
}
void InitTimer2 (void)
{
TCCR2A = 0;
TCCR2B = 0;
bitSet (TIMSK2, TOIE2); // Enable Timer2 interrupt, TIMSKx, Timer/Counter Interrupt Mask Register
TCCR2B = 0x05; // Prescaler = /128 (8 us resolution)
}
void Generator (void)
{
DDRB = B00111111; 
}
void ReadDelayPot (void)
{
value = analogRead(A3); // Wait for the ADC to finish
Sample1Delay = 65535 - 16 - value; 
Mikrosekunde = (65535 -Sample1Delay)/16;
}
// ISR() is the interrupt service routine for Timer2. The main loop is 
// triggered off this interrupt and must be completed before the next 
// interrupt.
ISR (TIMER2_OVF_vect)
{
TCNT2 = 47; // Reset the timer // 255-208 -> 1664us (~600 Hz)
//******************************** MAIN PULSE - TX ******************************
DIGITAL_OUT |= (1<<TX_PIN_A);  // digitalWrite (TX_PIN_A, HIGH);                  
VoidDelay (63935);  // 65535-63935=1600, 1600/16=100uS
DIGITAL_OUT &= ~(1<<TX_PIN_A);  // digitalWrite (TX_PIN_A, LOW);                  
//******************************** MAIN DELAY ***********************************
VoidDelay (Sample1Delay); // Main Delay pauza
//****************************** MAIN DELAY PULSE *******************************
DIGITAL_OUT |= (1<<SAMPLE_PIN_B);  // digitalWrite (SAMPLE_PIN_B, HIGH);             
VoidDelay (64850); // 65535-64850=685, 685/16=42,8125 uS
DIGITAL_OUT &= ~(1<<SAMPLE_PIN_B); // digitalWrite (SAMPLE_PIN_B, LOW);            
//******************************** EF DELAY *************************************
VoidDelay (65135); // 65535-65135=400, 400/16=25uS
//****************************** EF DELAY PULSE *********************************
DIGITAL_OUT |= (1<<SAMPLE_PIN_C);  // digitalWrite (SAMPLE_PIN_C, HIGH);                 
VoidDelay( 64850); // 65535-64850=685, 685/16=42,8125 uS
DIGITAL_OUT &= ~(1<<SAMPLE_PIN_C); // digitalWrite (SAMPLE_PIN_C, LOW);
//******************************** EF+TX DELAY **********************************
VoidDelay( 64850); // 65535-64850=685, 685/16=42,8125 uS
ReadDelayPot();
}

**ivconic** · 08-15-2019, 06:33 AM

Direct port/pin manipulation executes ~12 times faster, providing more accuracy and more than enough time and space for additional code.

**ivconic** · 08-15-2019, 09:01 AM

Many ways to skin a cat...

The poll is "which one of these is best?"

SAMPLE_PIN_C = 11

// make pin 11 LOW

1) digitalWrite (SAMPLE_PIN_C, LOW);
2) DIGITAL_OUT &= ~(1<<SAMPLE_PIN_C);
3) PORTB &=~ (1<<PORTB3);

**ossamaussama** · 08-15-2019, 12:23 PM

nice

**waltr** · 08-15-2019, 02:24 PM

Originally posted by ivconic View Post

Many ways to skin a cat...

The poll is "which one of these is best?"

The "best" depends on the Compiler and what other constraints are specified.

1) is a function call so does have the overhead of pushing and popping the stack at the least. Unless the "inline function" compilier option is selected.

2) Is abstracted by macros to be understood at a high level. ie: At the 'detector functional code level.

3) Is lower level referencing directly the hardware. It is good when troubleshooting with a scope as easy to know which IO pin. But, from the Detector code view point it is not known what the pin does.

If tight timing control is required and wish to view code from the "detector's functionality" then I would use method 2.

I may be abstract this with a macro:
#define SAMPLE_C_Low DIGITAL_OUT &= ~(1<<SAMPLE_PIN_C);

Then simply put in code:
SAMPLE_C_Low;

Of course there would be a macro to set pin output high.

Yes, many ways to write code.

**ivconic** · 08-15-2019, 02:48 PM

Originally posted by waltr View Post

The "best" depends on the Compiler and what other constraints are specified.

1) is a function call so does have the overhead of pushing and popping the stack at the least. Unless the "inline function" compilier option is selected.

2) Is abstracted by macros to be understood at a high level. ie: At the 'detector functional code level.

3) Is lower level referencing directly the hardware. It is good when troubleshooting with a scope as easy to know which IO pin. But, from the Detector code view point it is not known what the pin does.

If tight timing control is required and wish to view code from the "detector's functionality" then I would use method 2.

I may be abstract this with a macro:
#define SAMPLE_C_Low DIGITAL_OUT &= ~(1<<SAMPLE_PIN_C);

Then simply put in code:
SAMPLE_C_Low;

Of course there would be a macro to set pin output high.

Yes, many ways to write code.

**6666** · 08-17-2019, 11:47 PM

Hi Ivconic, sorry I got your name wrong, I am still suffering the effects of the flu, but thanks for having a sense of humour with my mistake.
But I think you are already a ICON.

I am interested in your Arduino modification to the Bara, as I always get confused with the correct way to bias JFETS and getting them to switch on and off correctly.
Some schematics use + and - 5 volts on the 40106 chip, others like the geotech bara rev A, use -5 volts and ground.

Your schematic shows the Arduino powered with +5 volts and ground,

Do you remember which version of the Bara pcb you were experimenting with ?.
Thanks for the code, I uploaded it to Arduino IDE and programmed my UNO and I can hear the pulses on the pins.
I will try an find my old Bara pcb and try it, thanks.

**ivconic** · 08-19-2019, 12:10 AM

This one:

**6666** · 08-19-2019, 12:25 AM

Originally posted by ivconic View Post

This one:
[ATTACH]47186[/ATTACH]

Thanks

**6666** · 08-19-2019, 01:18 AM

Last question (I hope) do you remember if you powered the Arduino from the 40106 socket on the PCB ? thanks.

**ivconic** · 08-19-2019, 09:10 AM

No, as far as i remember.
It was powered either from laptop's usb either from separate source.
I might replicate the situation again, if i find some free time today or these days.
Than i will record it again.

**6666** · 08-19-2019, 12:12 PM

Originally posted by ivconic View Post

No, as far as i remember.
It was powered either from laptop's usb either from separate source.
I might replicate the situation again, if i find some free time today or these days.
Than i will record it again.

Thanks I would be interested in seeing the recording.

Announcement

Question for Iconic , is this your Bara circuit

Question for Iconic , is this your Bara circuit

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment